import com.github.spotbugs.SpotBugsTask

project.extensions.extraProperties.set('SpotBugsTask', SpotBugsTask)

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'
apply plugin: 'maven'
apply plugin: 'maven-publish'
apply plugin: 'org.jetbrains.dokka'
apply from: '../ci/staticAnalysis/spotbugs/XxxxxxSpotBugs.gradle'


android {

    compileSdkVersion 29
    buildToolsVersion '29.0.3'

    afterEvaluate {
        def originalFilePath = "$buildDir/outputs/aar/XxxxxxZzzz-release.aar"
        def newFilePath = originalFilePath.replace(".aar", "_v${defaultConfig.versionName}.aar")
        def debugFile = file(originalFilePath)

        tasks.named("assembleRelease").configure {
            doLast {
                debugFile.renameTo(newFilePath)
            }
        }
    }

    defaultConfig {
        minSdkVersion 23
        targetSdkVersion 29
        versionCode 1
        versionName "1.9.0"
        multiDexEnabled true
        vectorDrawables.useSupportLibrary = true
        consumerProguardFiles '<http://proguard-rules.pro|proguard-rules.pro>'

        dimension "default"
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), '<http://proguard-rules.pro|proguard-rules.pro>'
        }
    }

    flavorDimensions "default"

    productFlavors {
        def useSecureFlagProd = rootProject.hasProperty("useSecureFlagProd") ? rootProject.useSecureFlagProd : true
        def useSecureFlagDev = rootProject.hasProperty("useSecureFlagDev") ? rootProject.useSecureFlagDev : false

        prod {
            buildConfigField 'boolean', 'USE_SECURE_FLAG', "$useSecureFlagProd"
        }

        dev {
            buildConfigField 'boolean', 'USE_SECURE_FLAG', "$useSecureFlagDev"
        }

    }

    repositories {
        flatDir {
            dirs 'libs'
        }
    }

    compileOptions {
        // Flag to enable support for the new language APIs
        // Source <https://developer.android.com/studio/write/java8-support>
        coreLibraryDesugaringEnabled true

        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = JavaVersion.VERSION_1_8
    }

    lintOptions {
        abortOnError false
    }

    testOptions {
        unitTests.returnDefaultValues = true
    }
}

dependencies {
    // Specify Versions here to avoid coupling this module with the app.
    def koinVersion = '2.1.6'

    api project(path: ':XxxxxxYyyyy')

    implementation fileTree(include: ['*.jar'], dir: 'libs')

    // Source: <https://developer.android.com/studio/write/java8-support>
    coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs:1.0.10'

    // Android x
    implementation 'androidx.appcompat:appcompat:1.2.0'
    implementation 'androidx.recyclerview:recyclerview:1.1.0'
    implementation 'androidx.legacy:legacy-support-v13:1.0.0'
    implementation 'androidx.vectordrawable:vectordrawable-animated:1.1.0'
    implementation 'androidx.constraintlayout:constraintlayout:1.1.3'
    implementation 'androidx.core:core:1.3.1'
    implementation 'androidx.legacy:legacy-preference-v14:1.0.0'

    // Google Play services
    implementation "com.google.android.gms:play-services-maps:17.0.0"
    implementation "com.google.android.gms:play-services-location:17.0.0"

    // When you update play-services-fitness to 18.0.0 or higher, observe the breaking changes
    // here: <https://developers.google.com/android/guides/releases#august_22_2019>
    implementation "com.google.android.gms:play-services-fitness:17.0.0"
    implementation "com.google.android.gms:play-services-auth:17.0.0"

    // Phone number parser
    implementation 'com.googlecode.libphonenumber:libphonenumber:8.11.3'

    // Barcode scanner
    implementation 'com.journeyapps:zxing-android-embedded:3.6.0'

    // Misc libs
    implementation "com.google.code.gson:gson:2.8.6"
    implementation 'com.squareup.okhttp3:okhttp:4.8.0'
    implementation "com.afollestad.material-dialogs:core:0.9.0.2"

    // Material components
    api "com.google.android.material:material:1.2.0"

    // Make this available to Zzzz and PAT.
    // (latest Picasso is 2.5.2, not 2.7xxx, see picasso's website)
    api "com.squareup.picasso:picasso:2.5.2"

    // Kotlin
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlinVersion"
    testImplementation "org.jetbrains.kotlin:kotlin-reflect:$kotlinVersion"

    // Kotlin Coroutines
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:$kotlinCoroutinesVersion"
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:$kotlinCoroutinesVersion"
    testImplementation "org.jetbrains.kotlinx:kotlinx-coroutines-test:$kotlinCoroutinesVersion"

    // Koin for Android
    implementation "org.koin:koin-android:$koinVersion"
    implementation "org.koin:koin-android-scope:$koinVersion"
    implementation "org.koin:koin-androidx-viewmodel:$koinVersion"
    testImplementation "org.koin:koin-test:$koinVersion"

    // Navigation Component
    implementation "androidx.navigation:navigation-fragment-ktx:2.3.0"
    implementation "androidx.navigation:navigation-ui-ktx:2.3.0"

    // Mockito framework
    testImplementation "org.mockito:mockito-core:3.4.6"
    testImplementation "com.nhaarman.mockitokotlin2:mockito-kotlin:2.2.0"

    // JUnit 4 framework
    testImplementation 'junit:junit:4.13'

    // OkHttp mock server
    testImplementation 'com.squareup.okhttp3:mockwebserver:4.3.1'
}

buildscript {
    ext {
        dokkaVersion = "1.4.0"
        kotlinVersion = "1.3.72"
        kotlinCoroutinesVersion = '1.3.6'
    }

    repositories {
        mavenCentral()
        google()
        jcenter()
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:${dokkaVersion}"
    }
}

//publishing pom configurations
def Zzzz_POM_GROUP = "com.Xxxxxx.Zzzz"
def Zzzz_POM_ARTIFACT_ID = "ZzzzSDK"

afterEvaluate { project ->
    uploadArchives {
        repositories {
            mavenDeployer {
                pom.groupId = Zzzz_POM_GROUP
                pom.artifactId = Zzzz_POM_ARTIFACT_ID
                pom.version = android.defaultConfig.versionName

                def deployPath = file('./')
                repository(url: "file://${deployPath.absolutePath}/../sdkOutput/")

                pom.whenConfigured { pom ->
                    pom.dependencies.forEach { dep ->
                        if (dep.getVersion() == "unspecified") {
                            dep.setVersion(android.defaultConfig.versionName)
                        }
                    }
                }
            }
        }
    }
}

// publishing task is not modifying the "unspecified" dependencies as uploadArchives does
publishing {
    publications {
        maven(MavenPublication) {
            groupId Zzzz_POM_GROUP
            artifactId Zzzz_POM_ARTIFACT_ID
            version android.defaultConfig.versionName
            artifact "$buildDir/../../sdkOutput/com/Xxxxxx/Zzzz/ZzzzSDK/${version}/ZzzzSDK-${version}.aar"

            //generate pom nodes for dependencies
            pom.withXml {
                def dependenciesNode = asNode().appendNode('dependencies')
                configurations.compile.allDependencies.each { dependency ->
                    def dependencyNode = dependenciesNode.appendNode('dependency')
                    dependencyNode.appendNode('groupId', dependency.group)
                    dependencyNode.appendNode('artifactId', dependency.name)
                    dependencyNode.appendNode('version', dependency.version)
                }
            }
        }
    }

    //publish to filesystem repo
    repositories{
        maven {
            url "$buildDir/repo"
        }
    }
}

.gradlew tasks

./gradlew :{app}:tasks