Why o why am I getting circular dependency issues? See thread for details.

# gradle

[Arjan van Wieringen]

Why o why am I getting circular dependency issues? See thread for details.

[Arjan van Wieringen]

// <root>/settings.gradle.kts
pluginManagement {
    repositories {
        gradlePluginPortal()
        google()
        mavenCentral()
        maven("<https://maven.pkg.jetbrains.space/public/p/compose/dev>")
    }
}

include(
    ":libraries:ui", 
    ":features:canvas:compose:ui",
)

[Arjan van Wieringen]

// libraries/ui/build.gradle.kts
plugins {
    kotlin("multiplatform")
}

kotlin {
    js(IR) {
        browser()
    }

    jvm()

    sourceSets {
        val commonMain by getting {
            dependencies {
                implementation(libs.jetbrains.compose.ui.geometry)
                implementation(libs.jetbrains.coroutines.core)
            }
        }
    }
}

[Arjan van Wieringen]

// features/canvas/compose/ui/build.gradle.kts
plugins {
    kotlin("multiplatform")
}

kotlin {
    js(IR) {
        browser()
    }

    jvm()

    sourceSets {
        val commonMain by getting {
            dependencies {
                implementation(project(":libraries:ui"))
            }
        }
    }
}

[Arjan van Wieringen]

This will not build because of:

Circular dependency between the following tasks:
:features:canvas:compose:ui:jsPackageJson
\--- :features:canvas:compose:ui:jsPackageJson (*)

[Adam S]

https://github.com/gradle/gradle/issues/847

Gradle doesn’t like it when multiple subprojects have the same GAV coordinates. You have two subprojects named ui.

Either rename the subprojects, or try setting the group to be distinct in each subproject

[Arjan van Wieringen]

Ah… that makes sense. Wow. Too bad the error reporting is so unclear in this case.

Thanks!

[Adam S]

yeah, I don’t mind the restriction, but a helpful warning message is really needed