Hello, I need some help. I have a small gradle.kts...

# javascript

[Philipp Smorygo [JB]]

Hello, I need some help. I have a small gradle.kts project with two subprojects: 1) multiplatform lib, 2) js module.

plugins {
    id("org.jetbrains.kotlin.multiplatform")
    id("org.jetbrains.kotlin.plugin.serialization")
}

repositories {
    mavenCentral()
    maven("<https://kotlin.bintray.com/kotlinx>")
}

kotlin {
    jvm()
    js()

    @Suppress("UNUSED_VARIABLE")
    sourceSets {
        commonMain {
            dependencies {
                implementation(kotlin("stdlib-common"))
                implementation("org.jetbrains.kotlinx:kotlinx-serialization-runtime-common:${Versions.kotlin_serialization_version}")
            }
        }
        val jvmMain by getting {
            dependencies {
                implementation(kotlin("stdlib-jdk8"))
                implementation("org.jetbrains.kotlinx:kotlinx-serialization-runtime:${Versions.kotlin_serialization_version}")
            }
        }
        val jsMain by getting {
            dependencies {
                implementation(kotlin("stdlib-js"))
                implementation("org.jetbrains.kotlinx:kotlinx-serialization-runtime-js:${Versions.kotlin_serialization_version}")
            }
        }
    }
}

import org.jetbrains.kotlin.gradle.dsl.Coroutines

plugins {
    kotlin("js")
    id("org.jetbrains.kotlin.plugin.serialization")
}

repositories {
    mavenCentral()
}

kotlin {
    experimental {
        coroutines = Coroutines.ENABLE
    }

    target {
        browser {
            runTask {}
        }
    }

    sourceSets {
        main {
            dependencies {
                implementation(kotlin("stdlib-js"))
                implementation(project(":common"))
            }
        }
    }
}

However gradle reports that "...Caused by: java.lang.IllegalStateException: project ':common' is not configured for JS usage"

What am I missing?

[Ilya Goncharov [JB]]

Could you please try to set

js {
    browser()
}

instead of

js()

In multiplatform module?

[Philipp Smorygo [JB]]

Okay, that does work. Thx. Seems like node and browser targets should be configured explicitly