I want to create a precompiled build script plugin...

# gradle

[Francesc]

I want to create a precompiled build script plugin for an Android app but I'm getting an error in the plug-in, android is not defined. Looks like I'm missing some dependencies possibly, does anybody have an example to follow or some hints on what the issue might be? Details in thread.

[Francesc]

in buildSrc, build.gradle.kts

plugins {
    `kotlin-dsl`
    `kotlin-dsl-precompiled-script-plugins`
}

repositories {
    mavenCentral()
    google()
}

[Francesc]

in buildSrc/src/main/kotlin/base-android-library.gradle.kts

plugins {
    id("com.android.library")
    id("kotlin-android")
}

android {
    compileSdk = Versions.compileSdkVersion
    compileSdkPreview = "Tiramisu"

    defaultConfig {
        minSdk = Versions.minSdkVersion
        targetSdk = Versions.targetSdkVersion
        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles("<http://consumer-rules.pro|consumer-rules.pro>")
    }

    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"),
                "<http://proguard-rules.pro|proguard-rules.pro>"
            )
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11
    }
    kotlinOptions {
        jvmTarget = Config.Compiler.jvmTarget
        freeCompilerArgs = freeCompilerArgs + Config.Compiler.freeCompilerArgs
    }
}

[tapchicoma]

in buildSrc/build.gradle.kts you need to add a common dependency on AGP

[Francesc]

thanks, I tried this but it doesn't work either

plugins {
    `kotlin-dsl`
    `kotlin-dsl-precompiled-script-plugins`
}

repositories {
    mavenCentral()
    google()
}

dependencies {
    classpath("com.android.tools.build:gradle:7.3.0-alpha07")
}

would you mind pointing me in the right direction?

[Francesc]

maybe this is what you mean?

buildscript {
    repositories {
        mavenCentral()
        google()
    }

    dependencies {
        classpath("com.android.tools.build:gradle:7.3.0-alpha07")
    }
}

plugins {
    `kotlin-dsl`
    `kotlin-dsl-precompiled-script-plugins`
}

but this prints > Cannot resolve external dependency org.jetbrains.kotlin:kotlin-stdlib-jdk8:1.5.31 because no repositories

[ephemient]

https://docs.gradle.org/current/userguide/custom_plugins.html#applying_external_plugins_in_precompiled_script_plugins

[Francesc]

thanks! that worked,

plugins {
    `kotlin-dsl`
    `kotlin-dsl-precompiled-script-plugins`
}

repositories {
    mavenCentral()
    google()
}

dependencies {
    implementation("com.android.tools.build:gradle:7.3.0-alpha07")
    implementation("org.jetbrains.kotlin:kotlin-gradle-plugin:1.6.10")
}

[Francesc]

I have a follow-up question, I'll make a separate thread